mod_bremsstrahlung.t

Go to the documentation of this file.

! Several bremsstrahlung cross sections are provided in this module
module mod_bremsstrahlung
  use mod_physics
  use mod_constants
  implicit none
 
  double precision, parameter :: r0=2.8179e-13,alpha=7.2992d-3
  double precision, parameter :: mec2=511.d0
 
contains
 
  subroutine bremcross_kramers(Z,Ee,Eph,sigmaB)
    ! Kramers bremsstrahlung cross section
    ! Z:ion change; Ee:electron energy (keV); Eph:photon energy (keV)
    ! sigmaB: cross section (cm^-2 keV^-1)
 
    integer :: Z
    double precision :: Eph,Ee,sigmaB
 
    double precision :: E1,E2,p1,p2,k
    double precision :: sigma0
 
    sigmab=0.d0
 
    if (ee>eph) then
      sigma0=(16.d0/3)*alpha*r0**2
      e1=ee/mec2  ! initial electron kinetic energy in units of mec2
      k=eph/mec2  ! photon energy in units of mec2
      e2=e1-k     ! kinetic energy of scattered electron
      p1=sqrt(e1*(2+e1))
      p2=sqrt(e2*(2+e2))
      sigmab=sigma0*z**2/(k*p1**2)
      sigmab=sigmab/mec2
    endif
 
  end subroutine bremcross_kramers
 
  subroutine bremcross_betheheitler(Z,Ee,Eph,sigmaB)
    ! Bethe-Heitler bremsstrahlung cross section
    ! Formula 3BN in Koch, Motz, Reviews of Modern Physics 31, 920 (1959)
    ! Z:ion change; Ee:electron energy (keV); Eph:photon energy (keV)
    ! sigmaB: cross section (cm^-2 keV^-1)
 
    integer :: Z
    double precision :: Eph,Ee,sigmaB
 
    double precision :: E1,E2,p1,p2,k
    double precision :: sigma0
 
    sigmab=0.d0
 
    if (ee>eph) then
      sigma0=(16.d0/3)*alpha*r0**2
      e1=ee/mec2  ! initial electron kinetic energy in units of mec2
      k=eph/mec2  ! photon energy in units of mec2
      e2=e1-k     ! kinetic energy of scattered electron
      p1=sqrt(e1*(2+e1))
      p2=sqrt(e2*(2+e2))
      sigmab=sigma0*z**2/(k*p1**2)*log((p1+p2)/(p1-p2))
      sigmab=sigmab/mec2
    endif
 
  end subroutine bremcross_betheheitler
 
  subroutine bremcross_haug(Z,Ee,Eph,sigmaB)
    ! Haug bremsstrahlung cross section
    ! Equation (4) and (5) in Haug, Astron. Astrophys. 326, 417 (1997)
    ! Z:ion change; Ee:electron energy (keV); Eph:photon energy (keV)
    ! sigmaB: cross section (cm^-2 keV^-1)
 
    integer :: Z
    double precision :: Eph,Ee,sigmaB
 
    double precision :: E1,E2,Et1,Et2,p1,p2,k
    double precision :: sigma0
    double precision :: term1,term2,term3,a1,a2,fE
 
    sigmab=0.d0
 
    if (ee>eph) then
      sigma0=2.d0*alpha*r0**2
      e1=ee/mec2  ! initial electron kinetic energy in units of mec2
      k=eph/mec2  ! photon energy in units of mec2
      e2=e1-k     ! kinetic energy of scattered electron
      p1=sqrt(e1*(2+e1))
      p2=sqrt(e2*(2+e2))
      et1=e1+1.d0  ! initial electron total energy
      et2=e2+1.d0  ! total energy of scattered electron
      
      term1=(4.d0/3)*et1*et2+k**2-(7.d0/15)*(k**2/(et1*et2))
      term1=term1-(11.d0/70)*(k**2)*(p1**2+p2**2)/(et1*et2)**4
      term2=2*log((et1*et2+p1*p2-1)/k)
      term3=1+(1/(et1*et2))+(7.d0/20)*(p1*2+p2*2)/(et1*et2)**3
      term3=term3+((9.d0/28)*k**2+(263.d0/210)*(p1**2)*(p2**2))/(et1*et2)**3
      term3=term3*(p1*p2)/(et1*et2)
 
      a1=alpha*z*et1/p1
      a2=alpha*z*et2/p2
      fe=(a2/a1)*(1.d0-exp(-2*dpi*a1))/(1.d0-exp(-2*dpi*a2))
 
      sigmab=sigma0*z**2/(k*p1**2)*term1*(term2-term3)*fe
      sigmab=sigmab/mec2
    endif
 
  end subroutine bremcross_haug
 
end module mod_bremsstrahlung